Как добавить внешний отчет в избранное 1С?
Для того, чтобы у внешнего отчета появилась возможность добавить его в список избранного, необходимо корректно заполнить параметры регистрации внешнего отчета Сведения о внешней обработке, аналогично тому как это реализовано в библиотеке стандартных подсистем (БСП).
Пример модуля объекта внешнего отчета
Функция СведенияОВнешнейОбработке() Экспорт
ОбщееОписание = "СведенияОВнешнейОбработкеОтчете";
ПараметрыРегистрации = Новый Структура;
ПараметрыРегистрации.Вставить("Вид" , "ДополнительныйОтчет");
ПараметрыРегистрации.Вставить("БезопасныйРежим" , Ложь);
ПараметрыРегистрации.Вставить("Наименование" , ОбщееОписание);
ПараметрыРегистрации.Вставить("Версия" , "1.1.0");
ПараметрыРегистрации.Вставить("Информация" , ОбщееОписание);
ТаблицаКоманд = ПолучитьТаблицуКоманд();
ДобавитьКоманду(ТаблицаКоманд, ОбщееОписание, "1", "ОткрытиеФормы", Истина, "");
ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
Возврат ПараметрыРегистрации;
Конецфункции
Функция ПолучитьТаблицуКоманд()
Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить("Представление" , Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Идентификатор" , Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Использование" , Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("ПоказыватьОповещение" , Новый ОписаниеТипов("Булево"));
Команды.Колонки.Добавить("Модификатор" , Новый ОписаниеТипов("Строка"));
Возврат Команды;
КонецФункции
Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры
Кроме того важно выбрать хранилище вариантов в свойствах отчета.
После этого необходимо заново загрузить отчет и попробовать его открыть.
Возможность добавления в избранное должна появиться, как на рисунке ниже.
